Cum se actualizează datele ca prima literă cu majuscule cu comanda t-sql? (Programare, Server Sql, Tsql, Actualizare Sql, Majuscule)

cethint a intrebat.

Am un tabel în baza mea de date. Numele tabelului meu este „Compania”. Vreau să schimb datele „nume_companie” ca prima literă majusculă. De exemplu;

„ABC COMPANY”

„DEF PLASTICITATE”

ca

„Abc Company”

„Def Plasticity”

Știu că ar trebui să folosesc comanda „UPDATE”. Dar cum? Vă mulțumesc pentru ajutor!

(CONCAT nu funcționează)

Comentarii

  • Ceea ce descrieți se numește „Title Case” și este discutat aici: stackoverflow.com/questions/9595356/proper-title-case-in-t-sql –  > Por Brian.
7 răspunsuri
Vishwanath Dalvi

SQL Server Nu aveți Initcap funcție ca oracle.

Puteți crea UDF pentru Initcap.

CREATE FUNCTION [dbo].[InitCap] ( @InputString varchar(4000) ) 
RETURNS VARCHAR(4000)
AS
BEGIN

DECLARE @Index          INT
DECLARE @Char           CHAR(1)
DECLARE @PrevChar       CHAR(1)
DECLARE @OutputString   VARCHAR(255)

SET @OutputString = LOWER(@InputString)
SET @Index = 1

WHILE @Index <= LEN(@InputString)
BEGIN
    SET @Char     = SUBSTRING(@InputString, @Index, 1)
    SET @PrevChar = CASE WHEN @Index = 1 THEN ' '
                         ELSE SUBSTRING(@InputString, @Index - 1, 1)
                    END

    IF @PrevChar IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&', '''', '(')
    BEGIN
        IF @PrevChar != '''' OR UPPER(@Char) != 'S'
            SET @OutputString = STUFF(@OutputString, @Index, 1, UPPER(@Char))
    END

    SET @Index = @Index + 1
END

RETURN @OutputString

END
GO

Verificarea funcționării UDF

select [dbo].[InitCap] ('stackoverflow com');

Stackoverflow Com

puteți actualiza tabelul dvs. astfel

update table
set column=[dbo].[InitCap](column);

Comentarii

  • Acest lucru este minunat! Mi-a salvat o mulțime de timp! Mulțumesc! –  > Por Bondt.
  • @mr_eclair foarte frumos 🙂 –  > Por senzacionale.
Andomar
update  YourTable
set     company_name = upper(substring(company_name,1,1)) + 
            lower(substring(company_name, 2, len(company_name)-1))
where   len(company_name) > 0

Exemplu live la SQL Fiddle.

Comentarii

  • Nu va seta doar prima literă cu majusculă. SO vrea ca prima literă a fiecărui cuvânt să fie majusculă, din câte îmi dau seama –  > Por Celălalt eu al meu.
  • prima literă a celui de-al doilea cuvânt este minusculă. Vreau să fac ca primele litere ale tuturor cuvintelor să fie majuscule. –  > Por cethint.
  • În acest caz, verificați linkul lui rhooligan –  > Por Andomar.
Mikael Eriksson

Cu puțin ajutor de la o funcție de divizare ca aceasta.

Încearcă asta, înlocuiește YourTable cu orice nume de tabel:

update T
set Name = P.Name
from YourTable as T
  cross apply (select (select upper(left(X.s, 1))+lower(stuff(X.s, 1, 1, ''))+' '
                       from dbo.split(' ', Name) as X
                       for xml path(''), type).value('.', 'varchar(50)')
              ) as P(Name)

Comentarii

  • Dar acestea sunt doar 2 exemple. Am o mulțime de date în tabel. Nu pot schimba una câte una sau mecanic. –  > Por cethint.
  • Ok, am eliminat chestiile care erau acolo doar pentru a putea testa acest lucru. –  > Por Mikael Eriksson.
  • De asemenea, trebuie să modificați 'varchar(50)' în orice tip de date este coloana Nume. –  > Por Mikael Eriksson.
BrownsFan

Cu o datorie față de postul de mai sus, această funcție scrie cu majusculă prima literă a fiecărui cuvânt, cu excepția celor care au mai puțin de o anumită lungime de caractere, care se presupune că sunt acronime. Dacă asta nu este o problemă, atunci setați al doilea argument la 0.

CREATE function [dbo].[f_camel_exc_short_words] (@InputString varchar(4000),@AcronymMaxLen INT )
RETURNS VARCHAR(4000)
AS
BEGIN

DECLARE @Index          INT
DECLARE @Char           CHAR(1)
DECLARE @PrevChar       CHAR(1)
DECLARE @Word           VARCHAR(255)
DECLARE @WordChar       CHAR(1)
DECLARE @OutputString   VARCHAR(255)
DECLARE @WordIndex      INT

SET @Word = ''
SET @OutputString = '' 
SET @Index = 1

WHILE @Index <= LEN(@InputString)+1
BEGIN
    SET @Char     = SUBSTRING(@InputString, @Index, 1)
    SET @PrevChar = CASE WHEN @Index = 1 THEN   ' '   ELSE   SUBSTRING(@InputString, @Index - 1, 1)  END

    --IF @Char IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&', '''', '(')
    --    SET @OutputString = @OutputString + @Char

    IF @PrevChar IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&', '''', '(','0','1','2','3','4','5','6','7','8','9') or @Index = LEN(@InputString)+1
    BEGIN
         SET @WordIndex = 1
        IF LEN(@Word) > @AcronymMaxLen 
        BEGIN
            WHILE @WordIndex <= LEN(@Word)
            BEGIN
                SET @WordChar = SUBSTRING(@Word,@WordIndex,1)
                if @WordIndex = 1  begin
                    SET @Word = STUFF(@Word,@WordIndex,1,UPPER(@WordChar))    end
                else    begin
                    SET @Word = STUFF(@Word,@WordIndex,1,LOWER(@WordChar))    end
                SET @WordIndex = @WordIndex + 1
            END
        END
        ELSE BEGIN
            SET @Word = UPPER(@Word)
        END
        set @OutputString = @OutputString + @Word
        SET @Word = ''
    END
    SET @Word = @Word + @Char
    SET @Index = @Index + 1
END  

return @OutputString

end
GO

Deci PRINT dbo.f_camel_exc_short_words ('PIONEER EURO BOND FUND CLASS C (NON-DIST) (EUR) (OFFSHORE) ISIN LU0119429891',4) returneazăPioneer EURO BOND FUND clasa C (NON-Dist) (EUR) (Offshore) ISIN LU0119429891

Sper că vă ajută.

Myk Syk

Încearcă asta:

declare @word as nvarchar (50)
set @word = 'ABC COMPANY'
select upper(left(@word, 1)) + lower(SUBSTRING(@word,2,charindex(' ', @word)-2)) + ' ' + 
upper(left(substring(@word,charindex(' ', @word)+1,len(@word)-1),1)) 
+ lower(SUBSTRING(@word,charindex(' ', @word)+2, len(@word)))

Bruce Sheffer

O altă modificare se ocupă de posesive (‘s) și de cuvintele care încep cu Mc

if ' ' + @OutputString like '% Mc%'
set @OutputString = ' ' + @OutputString
set @index = CHARINDEX ( ' Mc', @OutputString)
while @Index > 0
begin
    set @OutputString = SUBSTRING(@outputString, 1, @index + 2) + UPPER(SUBSTRING(@outputString, @index + 3, 1)) + SUBSTRING(@outputString, @index + 4, len(@outputString))
    set @index = CHARINDEX ( ' Mc', @OutputString, @Index + 4)
end
set @outputstring = ltrim(rtrim(@outputstring))

if @OutputString + ' ' like '%''S %' 
set @OutputString = ltrim(rtrim(REPLACE(@outputstring + ' ', '''S ', '''s ')))

se plasează chiar înainte de Return

user3183457
CREATE FUNCTION Initcap
( @mystring varchar(50) )
RETURNS VARCHAR(50)
AS
BEGIN
   DECLARE @val VARCHAR(50);
   SET @val = (select upper(left(@mystring,1)) +  lower(substring(@mystring,2,datalength(@mystring)-1)) )
   RETURN @val;
END;

Comentarii

  • Este mai bine să includeți un context/explicație în jurul codului, deoarece acest lucru face ca răspunsul să fie mai util pentru OP și pentru viitorii cititori (mai ales că aceasta este o întrebare veche cu mai multe răspunsuri de înaltă calitate). De asemenea, asigurați-vă că folosiți funcția de formatare a codului (lăsați o linie goală și apoi indentați cu patru spații) pentru a îmbunătăți lizibilitatea. –  > Por EJoshuaS – Reinscrieți-o pe Monica.